UNIVARIATEプロシジャ

例4.21 ベータ曲線の当てはめ

上限と下限の間で変化することがわかっている変数の分布を、ベータ分布を使用してモデル化することができます。この例では、ある製造会社がロボットアームを使用して、金属板へのヒンジの取り付けを行っています。取り付け位置は金属板の左端から10.1 mm内側にする必要があります。アームのばらつきのため、実際のオフセットは10.0～10.5 mmの間で変動します。次のステートメントは50か所の取り付け位置のオフセットを、変数Lengthの値としてデータセットRobotsに保存します。

data Robots;
   input Length @@;
   label Length = 'Attachment Point Offset (in mm)';
   datalines;
10.147 10.070 10.032 10.042 10.102
10.034 10.143 10.278 10.114 10.127
10.122 10.018 10.271 10.293 10.136
10.240 10.205 10.186 10.186 10.080
10.158 10.114 10.018 10.201 10.065
10.061 10.133 10.153 10.201 10.109
10.122 10.139 10.090 10.136 10.066
10.074 10.175 10.052 10.059 10.077
10.211 10.122 10.031 10.322 10.187
10.094 10.067 10.094 10.051 10.174
;

次のステートメントは出力4.21.1に示した、当てはめたベータ密度曲線を伴うヒストグラムを作成します。

title 'Fitted Beta Distribution of Offsets';
ods graphics off;
ods select ParameterEstimates FitQuantiles MyHist;
proc univariate data=Robots;
   histogram Length /
      beta(theta=10 scale=0.5 color=red fill)
      href      = 10
      hreflabel = 'Lower Bound'
      lhref     = 2
      vaxis     = axis1
      name      = 'MyHist';
   axis1 label=(a=90 r=0);
   inset n = 'Sample Size'
         beta / pos=ne  cfill=blank;
run;

ODS SELECTステートメントは出力を"ParameterEstimates"テーブルと"FitQuantiles"テーブルに制限します。ODSテーブル名のセクションを参照してください。BETA 1次オプションは当てはめたベータ分布を要求します。THETA= 2次オプションは下限しきい値を指定します。SCALE= 2次オプションは下限しきい値と上限しきい値の間の範囲を指定します。デフォルトのTHETA=およびSCALE=の値はそれぞれ0および1です。

出力4.21.1 ヒストグラムと当てはめたベータ曲線の重ね合わせ表示

FILL 2次オプションは、曲線の下の領域をCFILL=の色で塗りつぶすことを指定します(FILLが省略されている場合はこの代わりに、ヒストグラムの棒がCFILL=の色で塗りつぶされます)。

HREF=オプションは下限に参照線を描画し、HREFLABEL=オプションはラベルLower Boundを追加しています。LHREF=オプションは参照線の種類を点線に指定しています。INSETステートメントは標本サイズを示すインセットをプロットの右上端の位置に追加しています。

ベータ曲線の表示に加え、BETAオプションは曲線の当てはめの要約を要求します。この要約は出力4.21.2に示され、曲線のパラメータと観測および推定された分位点が含まれています。

この例のサンプルプログラムuniex12.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。