UNIVARIATEプロシジャ

インセットの配置

方位点の値を使用してインセットを配置する

方位点の位置を使用してインセットを配置するには、値N、NE、E、SE、S、SW、W、NWのいずれかをPOSITION=オプションとともに指定します。インセットのデフォルトの位置はNWです。次のステートメントは、8つの方位点のインセットの位置を示すヒストグラムを作成します。

data Score;
   input Student $ PreTest PostTest @@;
   label ScoreChange = 'Change in Test Scores';
   ScoreChange = PostTest - PreTest;
datalines;
Capalleti  94 91  Dubose     51 65
Engles     95 97  Grant      63 75
Krupski    80 75  Lundsford  92 55
Mcbane     75 78  Mullen     89 82
Nguyen     79 76  Patel      71 77
Si         75 70  Tanaka     87 73
;

title 'Test Scores for a College Course';
ods graphics off;
proc univariate data=Score noprint;
   histogram PreTest / midpoints = 45 to 95 by 10;
   inset n     / cfill=blank 
                 header='Position = NW' pos=nw;
   inset mean  / cfill=blank 
                 header='Position = N ' pos=n ;
   inset sum   / cfill=blank 
                 header='Position = NE' pos=ne;
   inset max   / cfill=blank 
                 header='Position = E ' pos=e ;
   inset min   / cfill=blank 
                 header='Position = SE' pos=se;
   inset nobs  / cfill=blank 
                 header='Position = S ' pos=s ;
   inset range / cfill=blank 
                 header='Position = SW' pos=sw;
   inset mode  / cfill=blank 
                 header='Position = W ' pos=w ;
   label PreTest = 'Pretest Score';
run;

図4.11 インセットの方位点

余白にインセットを配置する

プロット領域の周囲の4つの余白のいずれかにインセットを配置するには、値LM、RM、TM、BMのいずれかをPOSITION=オプションとともに指定します。余白への配置は、INSETステートメントで多くの統計量をリストする場合にお勧めします。プロット領域内に長いインセットを表示しようとすると、インセットがデータ表示の妨げになりやすくなります。

座標を使用してインセットを配置する

座標を使用してインセットを配置するには、POSITION=(x,y)を使用します。座標は軸データ単位または軸パーセンテージ単位(デフォルト)で指定します。注: ODS Graphics出力を作成する場合、座標を使用してインセットを配置することはできません。

DATAオプションを座標の直後に指定すると、PROC UNIVARIATEは軸データ単位を使用してインセットを配置します。たとえば、次のステートメントは、水平軸で45、垂直軸で10の位置にインセットの左下端を配置します。

title 'Test Scores for a College Course';
ods graphics off;
proc univariate data=Score noprint;
   histogram PreTest / midpoints = 45 to 95 by 10;
   inset n / header   = 'Position=(45,10)'
             position = (45,10) data;
run;

図4.12 インセットの座標位置

デフォルトでは、指定した座標はインセットの左下端の位置を決定します。この参照ポイントを変更するには、REFPOINT=オプションを使用します(後述)。

DATAオプションを省略すると、PROC UNIVARIATEは軸パーセンテージ単位を使用してインセットを配置します。軸パーセンテージ単位の座標は0～100である必要があります。ディスプレイの左下端の座標は(0,0)で、右上端の座標は(100, 100)です。たとえば、次のステートメントはヒストグラムを作成し、軸パーセンテージ単位の座標を使用して2つのインセットを配置します。

title 'Test Scores for a College Course';
ods graphics off;
proc univariate data=Score noprint;
   histogram PreTest / midpoints = 45 to 95 by 10;
   inset min / position = (5,25)
               header   = 'Position=(5,25)'
               refpoint = tl;
   inset max / position = (95,95)
               header   = 'Position=(95,95)'
               refpoint = tr;
run;

REFPOINT=オプションは、POSITION=オプションで指定した座標に配置するインセットの端を決定します。最初のインセットではREFPOINT=TLを使用しているため、水平軸方向が5%、垂直軸方向が25%の位置に、インセットの左上端が配置されます。2番目のインセットではREFPOINT=TRを使用しているため、水平軸方向が95%、垂直軸方向が95%の位置に、インセットの右上端が配置されます。

図4.13 インセットの参照ポイント

これらの例のサンプルプログラムunivar3.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。