UNIVARIATEプロシジャ

例4.16 二元比較ヒストグラムの作成

この例は二元比較ヒストグラムの作成方法を示しています。ある2つのサプライヤ(AおよびB)が、コンピュータメーカーにディスクドライブを供給しています。コンピュータメーカーは、2002年から2003年にかけて各サプライヤのばらつきに変化があったかどうかを判定するため、ディスクドライブの開口幅を測定しています。

次のステートメントはDiskという名前のデータセットに測定値を保存します。2つの分類変数SupplierおよびYearがあり、Yearにユーザー定義のフォーマットを関連付けています。

   proc format ;
      value mytime  1 = '2002' 2 = '2003';

   data Disk;
      input @1 Supplier $10. Year Width;
      label Width = 'Opening Width (inches)';
      format Year mytime.;
   datalines;
   Supplier A   1   1.8932
       .        .    .
   Supplier B   1   1.8986
   Supplier A   2   1.8978
       .        .    .
   Supplier B   2   1.8997
   ;

次のステートメントは出力4.16.1に示した比較ヒストグラムを作成します。

title 'Results of Supplier Training Program';
ods graphics off;
proc univariate data=Disk noprint;
   class Supplier Year / keylevel = ('Supplier A' '2003');
   histogram Width / intertile  = 1.0
                     vaxis      = 0 10 20 30
                     ncols      = 2
                     nrows      = 2;
run;

KEYLEVEL=オプションは、Supplierが'SUPPLIER A'に等しくYearが'2003'に等しいセルをキーセルに指定します。このセルによって他のセルのビン幅が決まり、このセルが左上端に表示されるように列が並べ替えられます。KEYLEVEL=オプションを指定しなかった場合、Supplierが'SUPPLIER A'に等しくYearが'2002'に等しいセルがデフォルトのキーセルになります。ラベル'2002'の列がラベル'2003'の列の左に表示されます。

VAXIS=オプションは垂直軸の目盛りラベルを指定します。NROWS=2およびNCOLS=2オプションは、のタイル配置を指定します。出力4.16.1は2002年から2003年にかけて、いずれのサプライヤもばらつきが低下していることを証明しています。

出力4.16.1 二元比較ヒストグラム

この例のサンプルプログラムuniex10.sasは、Base SASソフトウェアのSASサンプルライブラリに含まれています。