例3.9 Friedmanのカイ2乗検定

Friedmanの検定は、ランダム化された完全なブロックデザインにおける治療の違いに関するノンパラメトリック検定です。デザインの各ブロックは、単一の被験者か、または複数の被験者からなる等質グループになります。ブロックが被験者のグループである場合、各ブロック内の被験者の数は、治療の数に等しくなければなりません。治療は、各ブロック内で、被験者に対してランダムに割り当てられます。ブロックごとに1名の被験者が存在する場合、各被験者は、各治療の下で1回ずつ繰り返し測定されます。治療の順番は、各被験者に関してランダム化されます。

この設定では、Friedmanの検定は、分析でランクスコアを使用する場合(SCORES=RANK)のANOVA (行平均スコア) CMH統計量と同じになります。3元表は被験者(または被験者グループ)を層化変数として、治療を行変数として、反応を列変数として使用します。FREQプロシジャは、タイの反応値に中ランクを割り当てることにより、各タイを処理します。各ブロック内で治療ごとに複数の被験者が存在する場合、ANOVA CMH統計量は、Friedmanの検定の一般化となります。

データセットHypnosisには、催眠が4種類の感情に対応する皮膚電位(ミリボルト単位で測定)に関して同じ影響を与えるかどうかを調べた実験のデータが含まれています(Lehmann 1975, p. 264). この実験では、8名の被験者が、催眠下で、恐れ(fear)、喜び(joy)、悲しみ(sadness)、平穏(calmness)の各感情を示すよう求められます。データは、各感情につき被験者ごとに1つのオブザベーションとして記録されます。

data Hypnosis;
   length Emotion $ 10;
   input Subject Emotion $ SkinResponse @@;
   datalines;
1 fear 23.1  1 joy 22.7  1 sadness 22.5  1 calmness 22.6
2 fear 57.6  2 joy 53.2  2 sadness 53.7  2 calmness 53.1
3 fear 10.5  3 joy  9.7  3 sadness 10.8  3 calmness  8.3
4 fear 23.6  4 joy 19.6  4 sadness 21.1  4 calmness 21.6
5 fear 11.9  5 joy 13.8  5 sadness 13.7  5 calmness 13.3
6 fear 54.6  6 joy 47.1  6 sadness 39.2  6 calmness 37.0
7 fear 21.0  7 joy 13.6  7 sadness 13.7  7 calmness 14.8
8 fear 20.3  8 joy 23.6  8 sadness 16.3  8 calmness 14.8
;

次のPROC FREQステートメントでは、TABLESステートメントが、Subjectにより層化された三元表を作成します。変数Emotionと変数SkinResponseが、それぞれこの表の行および列になります。CMH2オプションは、最初の2つのCochran-Mantel-Haenszel統計量を生成します。SCORES=RANKオプションは、スコアランクを使用してこれらの統計量を計算するよう指定します。NOPRINTオプションは分割表の表示を抑制します。これらのステートメントが生成する出力を出力3.9.1出力3.9.2に示します。

proc freq data=Hypnosis;
   tables Subject*Emotion*SkinResponse / 
          cmh2 scores=rank noprint;
run;
proc freq data=Hypnosis;
   tables Emotion*SkinResponse /
          cmh2 scores=rank noprint;
run;

出力3.9.1に示されているCMH統計量はランクスコアに基づいているため、Row Mean Scores Differ統計量はFriedmanのカイ2乗統計量()と同じになります。値が0.0917であるということは、異なる感情による皮膚電位反応の差異は、10%水準では有意であるが、5%水準では有意でないことを示しています。

被験者別の層化を行わない場合、Row Mean Scores Differ CMH統計量はKruskal-Wallis検定と同じになり、有意ではありません(出力3.9.2では=0.9038と示されている)。このため、被験者の差異に起因するバックグラウンド変動を削減するためには、被験者に対する補正を行うことが重要となります。

出力3.9.1 CMH統計量:被験者別の層化
Clinical Trial for Treatment of Pain

The FREQ Procedure
 
Summary Statistics for Emotion by SkinResponse
Controlling for Subject

Cochran-Mantel-Haenszel Statistics (Based on Rank Scores)
Statistic Alternative Hypothesis DF Value Prob
1 Nonzero Correlation 1 0.2400 0.6242
2 Row Mean Scores Differ 3 6.4500 0.0917

出力3.9.2 CMH統計量:層化なし
Clinical Trial for Treatment of Pain

The FREQ Procedure
 
Summary Statistics for Emotion by SkinResponse

Cochran-Mantel-Haenszel Statistics (Based on Rank Scores)
Statistic Alternative Hypothesis DF Value Prob
1 Nonzero Correlation 1 0.0001 0.9933
2 Row Mean Scores Differ 3 0.5678 0.9038