欠損値

WEIGHT変数が欠損値である場合、FREQプロシジャはそのオブザベーションを分析で使用しません。

FREQプロシジャは、欠損値のBY変数値を、他のBY変数値と同じように取り扱います。欠損値は、独立した1つのBYグループを形成します。

あるオブザベーションがTABLESステートメントで要求された変数に関して欠損値を含んでいる場合、FREQプロシジャは、デフォルトではそのオブザベーションを度数表やクロス集計表に含めません。また、デフォルトでは、FREQプロシジャは、欠損値を含むオブザベーションをパーセンテージや統計量の計算に含めません。同プロシジャは、欠損値を含むオブザベーションの数を各表の下に表示します。

また、FREQプロシジャは、欠損値の数を出力データセット内に報告します。TABLESステートメントのOUT=データセットには、欠損値の度数を含む1つのオブザベーションが含められます。OUTPUTステートメントでNMISSオプションを指定すると、欠損値の度数を含む出力データセット変数が作成されます。

FREQプロシジャによるTABLES変数の欠損値の処理方法を変更するオプションとしては、次のものがあります。

MISSPRINT

欠損値の度数を度数表やクロス集計表に表示します。ただし、パーセンテージや統計量の計算には欠損値の度数を含めません。

MISSING

欠損値を、すべてのTABLES変数の有効な非欠損値レベルとして取り扱います。欠損値レベルを度数表やクロス集計表に表示し、パーセンテージや統計量の計算にも欠損値レベルを含めます。

FREQプロシジャでTABLES変数の欠損値を処理する3通りの方法を次に示します。次のDATAステートメントは、変数Aに欠損値を含むデータセットを作成します。

data one;
   input A Freq;
   datalines;
1 2
2 2
. 2
;

次のPROC FREQステートメントは、変数Aに関する一元度数表を作成します。最初の要求では欠損値オプションを指定していません。2番目の要求では、TABLESステートメントのMISSPRINTオプションを指定しています。3番目の要求では、TABLESステートメントのMISSINGオプションを指定しています。

proc freq data=one;
   tables A;
   weight Freq;
   title 'Default';
run;
proc freq data=one;
   tables A / missprint;
   weight Freq;
   title 'MISSPRINT Option';
run;
proc freq data=one;
   tables A / missing;
   weight Freq;
   title 'MISSING Option';
run;

図3.12に、この例で作成される度数表を示します。最初の表は、欠損値の処理に関するFREQプロシジャのデフォルトの振る舞いを示すものです。TABLES変数Aが欠損値であるオブザベーションは、この表には含められず、欠損値の度数がこの表の下に表示されます。2番目の表は、MISSPRINTオプションが指定された場合のものであり、この表には欠損値のあるオブザベーションが表示されていますが、そのオブザベーションの度数は合計度数やパーセンテージの計算には含められません。3番目の表は、MISSINGが指定された場合のものであり、この場合、FREQプロシジャは欠損値レベルを有効な非欠損値レベルとして扱うことを示しています。この表には欠損値レベルが表示されており、FREQプロシジャはこの欠損値レベルを度数やパーセンテージの計算に含めます。

図3.12 度数表における欠損値
Default

The FREQ Procedure

A Frequency Percent Cumulative
Frequency
Cumulative
Percent
1 2 50.00 2 50.00
2 2 50.00 4 100.00

Frequency Missing = 2


MISSPRINT Option

The FREQ Procedure

A Frequency Percent Cumulative
Frequency
Cumulative
Percent
. 2 . . .
1 2 50.00 2 50.00
2 2 50.00 4 100.00

Frequency Missing = 2


MISSING Option

The FREQ Procedure

A Frequency Percent Cumulative
Frequency
Cumulative
Percent
. 2 33.33 2 33.33
1 2 33.33 4 66.67
2 2 33.33 6 100.00

2元表の変数値の組み合わせが欠損値である場合、FREQプロシジャはその表セルの度数カウントにゼロを割り当てます。デフォルトでは、FREQプロシジャは欠損値の組み合わせをリスト形式では表示しません。また、FREQプロシジャは、デフォルトでは欠損値の組み合わせをOUT=出力データセットに含めません。欠損値の組み合わせを同データセットに含めるには、SPARSEオプションを、TABLESステートメントのLISTまたはOUT=オプションと共に指定します。