FREQプロシジャ

例3.1 度数の出力データセット

ヨーロッパの異なる2地域に住んでいる子供の目の色と髪の色をデータセットColorに記録するとします。子供1人につき1つのオブザベーションを記録するのではなく、データをセルカウントとして記録するため、変数Countには、それぞれ15種類の目の色と髪の色の組み合わせを示す子供の数が含められます。このデータセットには欠損値の組み合わせは含まれません。

SASデータセットColorを作成するDATAステップステートメントは次のようになります。

data Color;
   input Region Eyes $ Hair $ Count @@;
   label Eyes  ='Eye Color'
         Hair  ='Hair Color'
         Region='Geographic Region';
   datalines;
1 blue  fair   23  1 blue  red     7  1 blue  medium 24
1 blue  dark   11  1 green fair   19  1 green red     7
1 green medium 18  1 green dark   14  1 brown fair   34
1 brown red     5  1 brown medium 41  1 brown dark   40 
1 brown black   3  2 blue  fair   46  2 blue  red    21
2 blue  medium 44  2 blue  dark   40  2 blue  black   6
2 green fair   50  2 green red    31  2 green medium 37
2 green dark   23  2 brown fair   56  2 brown red    42
2 brown medium 53  2 brown dark   54  2 brown black  13
;

次のFREQステートメントは、Colorデータセットを読み取り、行がEyesで列がHairの2元表における度数、パーセンテージ、期待セル度数を含む出力データセットを作成します。次のTABLESステートメントは、3つの表を要求しています。すなわち、Eyesの度数表、Hairの度数表、および行がEyesで列がHairのクロス集計表です。OUT=オプションは、クロス集計表の度数を含むFreqCountデータセットを作成します。OUTEXPECTオプションは、表セルの期待度数をFreqCountデータセットに出力します。また、SPARSEオプションはゼロのセル度数をその出力データセットに含めます。WEIGHTステートメントでは、オブザベーションの重みを含む変数としてCountを指定しています。これらのステートメントが生成する出力を出力3.1.1～出力3.1.3に示します。

proc freq data=Color;
   tables Eyes Hair Eyes*Hair / out=FreqCount outexpect sparse;
   weight Count;
   title 'Eye and Hair Color of European Children';
run;

proc print data=FreqCount noobs;
   title2 'Output Data Set from PROC FREQ';
run;

出力3.1.1に、FREQプロシジャが作成する2つの度数表を示します。1つは眼の色の分布を示すものであり、もう1つは髪の色の分布を示すものです。デフォルトでは、FREQは変数値をアルファベット順にリスト表示します。'Eyes*Hair'という指定は、出力3.1.2に示すような、行が眼の色で列が髪の色が列であるクロス集計表を作成します。眼の色が緑で髪の色が黒のセル度数がゼロであることは、そのような目の色と髪の色の組み合わせがデータ内に存在しないことを意味しています。

出力データセットFreqCount (出力3.1.3)は、TABLESステートメントで最後に要求された行がEyesで列がHairの表における度数カウントとパーセンテージを含んでいます。SPARSEオプションが指定されているため、このデータセットは、度数がゼロのオブザベーションを含みます。また、OUTEXPECTオプションが指定されているため、変数Expectedには期待度数が含められます。