生存曲線のグラフにおける軸の設定

[質問]

LIFETESTプロシジャで「PLOTS=（S）」と指定し、生存曲線のグラフを作成しています。
このグラフにおける軸の設定等を変更することはできるのでしょうか。

[回答]

LIFETESTプロシジャでは、CENSOREDSYMBOL=オプションのように打ち切りの点を示すシンボルを指定するなど、一 部のオプションがありますが、軸の設定などより詳細な設定を行なうことができません。

しかし、PROC LIFETESTステートメントのOUTSURV=オプションを指定することによって、グラフを作成する際の元となる情報をデータセットに出力することができます。このデータセットを用いれば、GPLOTプロシジャで、軸の設定変更を加えた生存曲線のグラフを作成することができます。

具体的には、GPLOTプロシジャで作図をする前に、打ち切りの点を表示するために、一部データセットの加工を行ないます。
たとえば、変数TRTをSTRATAステートメントで指定し、OUTSURV=オプションにてデータセットOUTを作成した場合には、以下のような加工となります。

                              /* 打ち切り点表示のため、データセットを加工*/
   DATA out;
     SET out;
     BY STRATUM;
     new_trt = trt;
     OUTPUT;
                                     /* 各群における打ち切りの情報を追加 */
     IF _CENSOR_=1 THEN DO;
       IF trt=1 THEN new_trt=3;
       ELSE IF trt=2 THEN new_trt=4;
       OUTPUT;
     END;
   RUN;

その後、新しく作成した変数（new_trt）でデータセットの並べ替えを行なった後、GPLOTプロシジャを指定して作図します。

                                 /* 作成した変数NEW_TRTを用いて並べ替え */
   PROC SORT DATA=out;
     BY new_trt;
   RUN; 

                                                      /* 出力形式の作成 */
   PROC FORMAT;
     VALUE temp 1="trt=1" 
                2="trt=2"
                3="Censored trt=1"
                4="Censored trt=2";
   RUN;

                                      /* GPLOTプロシジャにてグラフの作成*/
   PROC GPLOT DATA=out;
     PLOT SURVIVAL*time=new_trt / VAXIS=axis1 HMINOR=0;
                                        /* 生存曲線のためのSYMBOLを指定 */
     SYMBOL1 W=1 L=2 I=STEPLJ CI=blue V=none;
     SYMBOL2 W=1 L=1 I=STEPLJ CI=red V=none;
                                      /* 打ち切り点のためのSYMBOLを指定 */
     SYMBOL3 H=1.3 I=NONE V=circle CV=blue;
     SYMBOL4 H=1.3 I=NONE V=circle CV=red;
                                                         /* 縦軸の指定 */
     AXIS1 LABEL = (ANGLE=-90 'Probability')
       ORDER = (0 to 1 by .50) MINOR = none OFFSET = (0.2)PCT;
     FORMAT new_trt temp.;
   RUN;
   QUIT;