ロジスティック回帰におけるタイプ3分析

[OS]ALL
[リリース] 8.1, 8.2
[キーワード] LOGISTICプロシジャ、CLASSステートメント、PARAM=REF、PARAM=GLM

[質問]

説明変数に交互作用を含むロジスティック回帰分析を行なっています。
その際にCLASSステートメントのオプションとしてPARAM=REFを指定した場合とPARAM=GLMと指定した場合のタイプ3分析(Type III Analysis of Effects)の結果が異なる場合があります。どうしてでしょうか?

[回答]

LOGISTICプロシジャにおいて交互作用を含めたタイプ3分析を実行すると、検定対象の帰無仮説が分類変数のパラメータ化によって異なります。そのため、表示される結果も違います。

PARAM=REFオプションを指定した際には、「主効果に対するパラメータが0である」という帰無仮説に対して検定を行ないます。このときに主効果を含む交互作用に対するパラメータを考慮していません。これに対し、PARAM=GLMオプションを用いると、「主効果の水準に違いがない」という帰無仮説を検定することになります。このとき、交互作用の効果を含めた上での検定を行なっています。

以下に例として次のようなモデルを考えます。ここではyを応答変数とし、AとBをそれぞれ2水準('1'または'2')からなる分類変数(主効果)とします。主効果Aに対するパラメータはラベルがA1となりますので、このラベルを使ってTESTステートメントを指定します。2つのTESTステートメントはPARAM=REFオプションを指定した際のタイプ3分析と同じ結果が得られます。

  proc logistic data=temp descending;
    class A B / param=ref;
    freq count;
    model y=A|B / scale=none aggregate;
    A  : test A1;  /*PARAM=REF 効果Aに対する検定*/
    B  : test B1;  /*PARAM=REF 効果Bに対する検定*/
  run;

これに対し、PARAM=GLMを指定した際には、交互作用に対するパラメータのラベルA1B1も用いて以下のようにTESTステートメントを指定します。これにより、タイプ3分析と同じ結果を出力することが可能となります。

proc logistic data=temp descending;
    class A B / param=glm;
    freq count;
    model y=A|B / scale=none aggregate;
    A  : test 2*A1+A1B1;  /*PARAM=GLM 効果Aに対する検定*/
    B  : test 2*B1+A1B1;  /*PARAM=GLM 効果Bに対する検定*/
  run;