MIXEDプロシジャでの反復測定の出力について

[質問]

MIXEDプロシジャによって反復測定データを解析した時に、REPEATEDステートメントで誤差にTYPE=CS(Coumpound Symmetry)を指定した時の結果と、RANDOMステートメントで被験者の変量効果を指定した時の結果が異なる時があります。2モデルの分散共分散構造は同じになると予想されますが、どうして異なった結果になるのでしょうか？

(サンプルデータ)

        data data1;
         do group=1 to 2;
          do id=1 to 4;
           do time=1 to 4;
             input resp@@;
             output;
           end;
          end;
         end;
        cards;
        11.1 12.5 14.1  18.5
        10.4 12.4 10.2  19.0
        11.2 14.1 10.9  12.5
        10.4 10.7 21.2  14.5
        11.2 15.1 14.4  18.1
        10.4 12.3 11.1  14.8
        11.2 14.2 17.9  12.0
        12.4 10.3 22.1  14.2
        ;
        run;
	
(サンプルプログラム1)

        proc mixed data=data1;
          class id group time;
          model resp=group time group*time;
          repeated time /subject=id(group) type=cs;
        run;
	
(サンプルプログラム1の結果)
	
            Tests of Fixed Effects
	
        Source       NDF   DDF  Type  III F  Pr > F
	
        GROUP          1     6         0.42  0.5408
        TIME           3    18         3.50  0.0370
        GROUP*TIME     3    18         0.43  0.7362
	
(サンプルプログラム2)

        proc mixed data=data1;
          class id group time;
          model resp=group time group*time;
          random id(group);
        run;
	
(サンプルプログラム2の結果)
	
             Tests of Fixed Effects
	
        Source       NDF   DDF  Type  III F  Pr > F
	
        GROUP          1     6         0.22  0.6521
        TIME           3    18         4.04  0.0232
        GROUP*TIME     3    18         0.49  0.6917

[回答]

REPEATEDステートメントにおいてTYPE=CSを指定した時、誤差の共分散は負になることが許されています。一方、RANDOMステートメントを用いた時、デフォルトでは変量効果の分散推定値は0以上の値をとる制約が課せられています。そのため、変量効果の分散が負に推定されるようなデータの時には、両者の結果には違いが生じます。なお、PARMSステートメントにNOBOUNDオプションを指定すると、分散推定値に対する負の推定値を許すことになりますが、0以上の制約はなくなります。

(例)

   proc mixed data=data1;
     parms /nobound;
     class id group time;
     model resp=group time group*time;
     random id(group);
   run;