GPLOTプロシジャで、複数の参照線の色や線種を個別に指定する（SAS 8.1以前）

[OS]ALL
[リリース] 6.12, 8.1
[キーワード] VREF, HREF, ANNOTATE

[質問]

「GPLOTプロシジャでVREFオプションを使って複数の参照線を描いています。
参照線の色や線の種類を１本ずつ個別に指定できますか？

[回答]

SAS 8.2より前のリリースでは、VREFオプション、およびHREFオプションで描かれる参照線の色や線種を１本ずつ個別に指定することはできません。指定できる参照線の色と線種は、1種類です。しかし、ANNOTATE機能を使用すれば、１本ずつ参照線を描くことができます。

例：縦軸の100, 150, 200に参照線を描く 

                                        /* サンプルデータの作成 */ 
  DATA a;
    INPUT x y @@;
  CARDS;
  10  77 20 200 30 230
  15 150 25 210 35 210
  ;
  RUN;
                                   /* ANNOTATEデータセットの作成 */
  DATA _anno;
    LENGTH function $8;
    RETAIN xsys '1' ysys '2' when 'a';
    FUNCTION='move'; x=0;   y=100;                          OUTPUT;
    FUNCTION='draw'; x=100; y=100; line=10; color='blue';   OUTPUT;
    FUNCTION='move'; x=0;   y=150;                          OUTPUT;
    FUNCTION='draw'; x=100; y=150; line=3;  color='green';  OUTPUT;
    FUNCTION='move'; x=0;   y=200;                          OUTPUT;
    FUNCTION='draw'; x=100; y=200; line=1;  color='red';    OUTPUT;
  RUN;

  PROC GPLOT DATA=a ANNO=_anno;      /* ANNO=ANNOTATEデータセット名 */
    PLOT y*x;
  RUN;
  QUIT;

なお、SAS 8.2では、追加された機能を使っても実現できます。