FREQ、TABULATEプロシジャの出力の罫線を実線にする

[質問]

FREQやTABULATEプロシジャなど、罫線文字で作られた表の罫線を実線に変換できますか。

[回答]

SAS 6.08のSAS/GRAPHで追加されたJPRINTプロシジャを使うと、-や|などの文字で表された罫線を実線に変換できます。
このプロシジャは従来からあるGPRINTプロシジャと同様に、テキストファイルをページ単位でグラフイックに変換します。
ただし変換の際に、JPRINTプロシジャは、文字=-|<>+の組み合わせで構成された罫線を検出し、これを実線等に置き換えます。
TABULATEプロシジャをはじめ、FREQ、PLOT、CHART、TIMEPLOT、GANTTプロシジャなど、表、文字グラフ出力を行うプロシジャの結果を変換することができます。
構文および指定方法は、GPRINTプロシジャと同一です。以下にその例を示します。

  options ls=80 ps=24 nodate nonumber;
  data sales;
    input region dept sales;
  cards;
  1 1 1200
  1 2  340
  1 3  860
  2 1  830
  2 2 1000
  ;
  proc format;
    value regfmt  1='東京'
                  2='大阪'
                  3='名古屋';
    value deptfmt 1='第一課'
                  2='第二課'
                  3='第三課';
  run;
  filename ft21f001 'table.lis';
  proc printto unit=21 new;
  run;
  proc tabulate data=sales;
    class region dept;
    var sales;
    keylabel sum=' ' pctsum=' ' n=' ';
    label region='地区'
          dept  ='部門'
          sales ='売上';
    table region*dept all='全営業所',
          sales*(sum*f=yen8. pctsum<all dept> n)
          /rts=20;
    format region regfmt. dept deptfmt. sales yen8.;
  run;
  proc printto; run;
  goptions hpos=80 vpos=24 simfont=mincho;
  title f=kanji h=1 'JPRINTプロシジャの実行結果';
  proc jprint unit=21;
  run;

[参考]

• 「SAS Technical Report J-118: 日本語/DBCS機能使用の手引き, Release 6.08, 6.09」(注文番号 19118)